SOMASE Excel: Como fazer uma fórmula com a função SOMASE?


Somase Excel Função e Fórmula
Somase Excel Função e Fórmula

Allisson da Silva
CEO da Compra Ae. Fundador da Osruc.

O que é a função SOMASE?

O SOMASE é uma função do Excel para uso em fórmulas que pertence as categorias de aritmética e lógica do editor de planilhas da Microsoft .

Ela possui três partes para preenchimento, onde duas deles são obrigatórias. (O intervalo e o critério)

O SOMASE do Excel está habilitado para interpretar operadores lógicos como >, <, <> e =, assim como a função está habilitada para caracteres curingas (* ou  ?).

Este artigo irá lhe mostrar em cerca de 10 minutos como construir uma fórmula com a função, assim como apresentará exemplos que possam esclarecer com mais propriedade o uso do recurso em sua planilha.

Apresentando como usar a função de adição condicional SOMASE do Excel

Caso prefira, assista no YouTube: Somase Excel


Aprenda mais com nosso Curso de Excel


Objetivo: Para que serve?

Realizar uma soma tomando por base um teste lógico verdadeiro comparando o critério com o intervalo.

Como fazer uma fórmula com a função SOMASE?

=SOMASE(Intervalo, Critério, [Intervalo Soma])

Argumentos

A fórmula do  SOMASE usa os seguintes argumentos:

Intervalo (argumento obrigatório) - Este é o intervalo de células ao qual queremos aplicar os critérios.

Critério (argumento obrigatório) - São os critérios usados ​​para determinar quais células precisam ser adicionadas.

Quando fornecemos o argumento de critérios, ele pode ser:

- Um valor numérico (que pode ser um número inteiro, decimal, data, hora ou valor lógico) (por exemplo, 10, 01/01/2018, VERDADEIRO) ou

- Uma string de texto (por exemplo, “Texto”, “Quinta-feira”)

ou

- Uma expressão (por exemplo, “> 12”, “<> 0”).

Intervalo Soma (argumento opcional) - Esta é uma matriz de valores numéricos (ou células contendo valores numéricos) que devem ser somados se a entrada de intervalo correspondente satisfizer os critérios fornecidos. Se o argumento [Intervalo Soma] for omitido, os valores do argumento intervalo serão somados. 

Valor de retorno

Um número resultante da operação de soma.

Como usar a função SOMASE do Excel?

Para entender o uso da função SOMASE, vamos considerar as etapas abaixo: 

1. Preencha um intervalo da planilha com dados

Como fazer uma Fórmula com a Função Somase do Excel - Step1
Como fazer uma Fórmula com a Função Somase do Excel - Step1

O primeiro passo para usar a função é criar uma planilha com dados, sendo que uma coluna deverá ter dados numéricos para que a soma seja aplicada. Para isso considere o intervalo apresentado pela na próxima tabela. Copie e cole a tabela no seu Excel começando da célula B5:

PRODUTO COR QUANTIDADE
CAMISA VERÃO AZUL 3
SHORT INVERNO VERDE 15
CALSA VERÃO PRETO 7
BLUSÃO INVERNO VERDE 1
PIJAMA VERÃO LARANJA 2
CAMISA INVERNO VERMELHO 2
SHORT VERÃO AZUL 5
CAMISA VERÃO AMARELO 14
BLUSÃO INVERNO ROXO 19
PIJAMA VERÃO CINZA 3
CAMISA INVERNO VERDE 10
SHORT VERÃO LARANJA 4

2. Crie um intervalo para o critério

Como fazer uma Fórmula com a Função Somase do Excel - Step2
Como fazer uma Fórmula com a Função Somase do Excel - Step2

A criação de um intervalo para ser usado como critério é opcional, mas o campo critério da função deve ser obrigatoriamente preenchido. Agora deverá ser criado um intervalo para seleção do campo critério. Para o exemplo copie e cole em seu Excel na célula F5 a seguinte tabela:

PRODUTO QUANTIDADE
BLUSÃO INVERNO  =SOMASE($B$6:$B$17;$F6;$D$6:$D$17)
CALSA VERÃO  
CAMISA INVERNO  
CAMISA VERÃO  
PIJAMA VERÃO  
SHORT INVERNO  
SHORT VERÃO  

3. Inicie a fórmula identificando um intervalo

Como fazer uma Fórmula com a Função Somase do Excel - Step3
Como fazer uma Fórmula com a Função Somase do Excel - Step3

Agora que um novo intervalo foi criado, o próximo passo é escolher uma célula para a criação da fórmula. No seu Excel na célula G6 copie e cole a seguinte fórmula:

=SOMASE($B$6:$B$17;$F6;$D$6:$D$17)

Caso já tenha copiado o exemplo do passo anterior, não será preciso colar novamente a fórmula.

4. Identifique ou crie os critérios

Como fazer uma Fórmula com a Função Somase do Excel - Step4
Como fazer uma Fórmula com a Função Somase do Excel - Step4

Nessa etapa observe $F6 na imagem. Ele foi adicionado a função pois define onde o Excel irá pegar a informação para pesquisar no intervalo definido no passo anterior $B$6:$B$17.

Nesse exemplo o critério foi apontado para a célula $F6, onde o editor irá buscar seu conteúdo, mas o usuário poderia digitar o os termos "BLUSÃO INVERNO" que teria o mesmo efeito.

5. Aplique opcionalmente o  intervalo de soma

Como fazer uma Fórmula com a Função Somase do Excel - Step5
Como fazer uma Fórmula com a Função Somase do Excel - Step5

Agora, caso queira, o editor de planilha opcionalmente dá a possibilidade de usar o Intervalo de Soma para enriquecer o uso da função. Nessa etapa, a imagem apresenta o conteúdo do terceiro campo preenchido com $D$6:$D$17. Esse intervalo será somado recursivamente célula a célula desde que teste verdadeiro para o critério apresentado em $B$6:$B$17 comparado a $F6.

Como fazer um SOMASE com duas condições?

Um SOMASE pode ser usado com duas ou mais condições usando duas estratégias: concatenação (vários critérios na mesma coluna) e o uso da função SOMASES.

Concatenação

A função pode ser feita usando vários critérios em uma mesma coluna por intermédio da concatenação de textos.

Um dos métodos para concatenar um texto é usar o operador &. Então se eu quiser formar uma frase usando os dados da tabela acima, como a frase CAMISA VERÃO AZUL, eu teria que realizar o seguinte procedimento:

Primeiro como a frase CAMISA VERÃO está na célula B6 e a palavra AZUL está na célula C6, para construir a frase proposta anteriormente eu deveria construir em qualquer célula diferente de B6 e C6 a fórmula:

=$B6&""&$C6

O resultado seria a frase CAMISA VERÃO AZUL. Se eu remover o &" "& do meio das referências das duas células, e trocasse por apenas um =$b6&$C6 o resultado final sairia sem espaço como, CAMISA VERÃOAZUL.

Então pensando sobre isso, e se a sua meta fosse fazer uma soma usando as duas condições CAMISA VERÃO e só que da cor AZUL, eu teria que criar uma nova coluna na tabela com todas as concatenações das colunas PRODUTO e COR.

Com essa coluna concatenada com vários critérios em uma mesma coluna, a qual eu vou dar o nome de CHAVE, agora o meu intervalo seria essa nova coluna concatenada e o critério eu poderia facilmente usar esses dois filtros, produto e cor, para realizar a minha soma.

Copie e cole no seu Excel na célula B5 a seguinte tabela:

PRODUTO COR QUANTIDADE CHAVE PRODUTO COR QUANTIDADE
CAMISA VERÃO AZUL 3 =B6&" "&C6 CAMISA VERÃO AZUL =SOMASE($E:$E;$G6&" "&$H6;$D:$D)
SHORT INVERNO VERDE 15 =B7&" "&C7
CALSA VERÃO PRETO 7 =B8&" "&C8
BLUSÃO INVERNO VERDE 1 =B9&" "&C9
PIJAMA VERÃO LARANJA 2 =B10&" "&C10
CAMISA INVERNO VERMELHO 2 =B11&" "&C11
SHORT VERÃO AZUL 5 =B12&" "&C12
CAMISA VERÃO AMARELO 14 =B13&" "&C13
BLUSÃO INVERNO ROXO 19 =B14&" "&C14
PIJAMA VERÃO CINZA 3 =B15&" "&C15
CAMISA INVERNO VERDE 10 =B16&" "&C16
SHORT VERÃO LARANJA 4 =B17&" "&C17
CAMISA VERÃO AZUL 4 =B18&" "&C18

SOMASES

Uma outra maneira de realizar uma soma com mais de um critério seria usar a função desenvolvida exatamente para isso, que é a SOMASES.

A função SOMASES do Excel foi criada para resolver o problema de fazermos somas com diferentes filtros.

Qual a diferença do SOMASE para o SOMASES?

A diferença do SOMASE para o SOMASES é que este segundo pode aceitar dezenas de critérios, enquanto o primeiro, o SOMASE, não. Ele aceita apenas um critério.

No SOMASES a estrutura da fórmula muda um pouco da que aprendemos aqui nesse artigo. O primeiro critério da função agora é o intervalo de soma, e todos os outros vão ser Intervalo de pesquisa e Critério, sempre aos pares. Veja:

=SOMASES(Intervalo Soma; Intervalo1; Critério1; Intervalo2; Critério2)

Veja que depois do intervalo soma, inserimos sempre pares de Intervalo (coluna onde se busca) e Critério (o que se busca). Assim podemos usar com essa função diversos critérios para nossa formula de adição.

O Exemplo anterior poderia ser resolvido assim:

PRODUTO COR QUANTIDADE PRODUTO COR QUANTIDADE
CAMISA VERÃO AZUL 3 CAMISA VERÃO AZUL =SOMASES($D:$D;$B:$B;$F6;$C:$C;$G6)
SHORT INVERNO VERDE 15
CALSA VERÃO PRETO 7
BLUSÃO INVERNO VERDE 1
PIJAMA VERÃO LARANJA 2
CAMISA INVERNO VERMELHO 2
SHORT VERÃO AZUL 5
CAMISA VERÃO AMARELO 14
BLUSÃO INVERNO ROXO 19
PIJAMA VERÃO CINZA 3
CAMISA INVERNO VERDE 10
SHORT VERÃO LARANJA 4
CAMISA VERÃO AZUL 4

SOMASE com data no Excel

Muitas vezes você precisará fazer uma fórmula no Excel utilizando datas em suas adições, e se seu caso for com o uso do SOMASE, vermos logo adiante entender como fazer somas com critérios de datas.

No Excel uma data é um número, então caso você esteja em dúvida se está ou não trabalhando com data, multiplique a célula que tem a data que você deseja operar por 1. Fazendo isso, se nesse campo tiver uma data, em um formato entendido pelo programa seu resultado poderá ser formatado pelo tipo data.

Agora que você tem a data numérica, efetue a mesma operação em todas as datas dos critérios e intervalos. Agora use as mesmas regras de soma dessa publicação.

Você também poderá fazer a operação com datas no formato texto, para isso converta a data em texto, tanto do lado do critério quanto do intervalo.

Para converter uma data em texto basta fazer uma concatenação da célula com o valor da data com "".

Exemplo:

=A1&""

Se na célula A1 tiver uma data, após você realizar essa operação o conteúdo da célula deixará de ser data (número) e passará a ser um texto.

Exemplos de SOMASE

Some todos os dados da coluna B se encontrar um 2 na célula da coluna A

=SOMASE(A:A;2;B:B)

Some todos os dados da coluna B se encontrar um valor maior que 2 na célula da coluna A

=SOMASE(A:A;">2";B:B)

Some todos os dados da coluna B se encontrar um valor menor ou igual a 2 na célula da coluna A

=SOMASE(A:A;"<=2";B:B)

Some todos os dados da coluna B se encontrar um valor diferente de 2 na célula da coluna A

=SOMASE(A:A;"<>2";B:B)

Some todos os dados da coluna B se encontrar uma palavra AZUL na célula da coluna A

=SOMASE(A:A;"AZUL";B:B)

Some todos os dados da coluna B se encontrar uma palavra ou frase que comece com AZUL na célula da coluna A

=SOMASE(A:A;"AZUL*";B:B)

Some todos os dados da coluna B se encontrar uma palavra ou frase que termine com AZUL na célula da coluna A

=SOMASE(A:A;"*AZUL";B:B)

Some todos os dados da coluna B se encontrar uma palavra ou frase que em seu interior tenha a palavra AZUL na célula da coluna A

=SOMASE(A:A;"*AZUL*";B:B)

Some todos os dados da coluna B se encontrar uma palavra que tenha COMPRA, mas aceitando 1 caractere depois, na célula da coluna A

=SOMASE(A:A;"COMPRA?";B:B)

Esse último aceitará COMPRAS ou COMPRAR, pois a interrogação substituirá o S ou o R das palavras.

Notas sobre a fórmula feita com a função

1. #VALOR! erro - ocorre quando o critério fornecido é uma string de texto com mais de 255 caracteres.

2. Quando [Intervalo Soma] for omitido, as células no intervalo serão somadas.

3. Os seguintes curingas podem ser usados ​​em critérios relacionados ao texto:

  • ? - corresponde a qualquer caractere único
  • * - corresponde a qualquer sequência de caracteres
  • Para localizar um ponto de interrogação ou asterisco literal, use um til (~) antes do ponto de interrogação ou asterisco (por exemplo, ~ ?, ~ *).

Versões compatíveis do Excel para o SOMASE

Excel do Microsoft 365, Excel do Microsoft 365 para Mac, Excel para a Web Excel 2021, Excel 2021 para Mac, Excel 2019, Excel 2019 para Mac, Excel 2016, Excel 2016 para Mac, Excel 2013, Excel 2010, Excel 2007, Excel para Mac 2011, Excel Starter 2010


Baixe o arquivo da planilha Excel grátis


Envie para alguém:

https://is.gd/somaseexcel
https://bit.ly/somaseexcel
http://ow.ly/abU950JrXNc



O que você achou?

Compartilhe:





Nenhum comentário publicado ainda.
Faça login para poder comentar




FaceFace